From: perceval.arenou@ptxtrimble.com
To: openembedded-devel@lists.openembedded.org
Cc: Perceval Arenou <perceval.arenou@gmail.com>
Subject: [meta-multimedia][PATCH] aravis: new recipe aravis is a vision library for genicam based cameras. aravis project allows to stream from genicam and GigE cameras
Date: Wed, 17 Apr 2024 16:04:12 +0200 [thread overview]
Message-ID: <20240417140412.87875-1-perceval.arenou@ptxtrimble.com> (raw)
[-- Attachment #1: Type: text/plain, Size: 2336 bytes --]
From: Perceval Arenou <perceval.arenou@gmail.com>
---
.../aravis/aravis_0.8.31.bb | 45 +++++++++++++++++++
1 file changed, 45 insertions(+)
create mode 100644 meta-multimedia/recipes-multimedia/aravis/aravis_0.8.31.bb
diff --git a/meta-multimedia/recipes-multimedia/aravis/aravis_0.8.31.bb b/meta-multimedia/recipes-multimedia/aravis/aravis_0.8.31.bb
new file mode 100644
index 000000000..f2bbad674
--- /dev/null
+++ b/meta-multimedia/recipes-multimedia/aravis/aravis_0.8.31.bb
@@ -0,0 +1,45 @@
+SUMMARY = "A vision library for genicam based cameras"
+DESCRIPTION = "\
+ Aravis is a glib/gobject based library for video acquisition using Genicam cameras.\
+ It currently implements the gigabit ethernet and USB3 protocols used by industrial cameras.\
+ It also provides a basic ethernet camera simulator and a simple video viewer.\
+"
+AUTHOR = "Emmanuel Pacaud"
+HOMEPAGE = "https://github.com/AravisProject/aravis"
+LICENSE = "LGPL-2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+DEPENDS += "\
+ glib-2.0 \
+ glib-2.0-native \
+ intltool-native \
+ libxml2 \
+ zlib \
+"
+
+SRC_URI = "https://github.com/AravisProject/aravis/releases/download/${PV}/${BPN}-${PV}.tar.xz"
+SRC_URI[sha256sum] = "9c4ebe6273ed3abe466cb6ed8fa5c132bdd7e9a9298ca43fa0212c4311a084da"
+
+S = "${WORKDIR}/${BPN}-${PV}"
+
+# These options are found in AravisProject/aravis meson_options.txt
+EXTRA_OEMESON += "\
+ -Ddocumentation=disabled \
+ -Dfast-heartbeat=false \
+ -Dpacket-socket=enabled \
+ -Dtests=false \
+"
+
+PACKAGECONFIG ?= ""
+PACKAGECONFIG[gstreamer] = "-Dgst-plugin=enabled, -Dgst-plugin=disabled, gstreamer1.0 gstreamer1.0-plugins-base,"
+PACKAGECONFIG[introspection] = "-Dintrospection=enabled, -Dintrospection=disabled, gobject-introspection,"
+PACKAGECONFIG[usb] = "-Dusb=enabled, -Dusb=disabled, libusb1,"
+PACKAGECONFIG[viewer] = "-Dviewer=enabled, -Dviewer=disabled, gtk+3 gstreamer1.0-plugins-base,"
+
+# needs to be after PACKAGECONFIG to make sure it is defined
+inherit meson pkgconfig ${@bb.utils.contains('PACKAGECONFIG', 'introspection', 'gobject-introspection', '', d)}
+
+FILES:${PN} += "\
+ ${datadir} \
+ ${libdir}/gstreamer-1.0/libgstaravis.0.8.so \
+"
--
2.43.0
[-- Attachment #2: Type: text/html, Size: 3025 bytes --]
next reply other threads:[~2024-04-17 14:04 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-04-17 14:04 perceval.arenou [this message]
2024-04-17 14:54 ` [oe] [meta-multimedia][PATCH] aravis: new recipe aravis is a vision library for genicam based cameras. aravis project allows to stream from genicam and GigE cameras Ross Burton
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20240417140412.87875-1-perceval.arenou@ptxtrimble.com \
--to=perceval.arenou@ptxtrimble.com \
--cc=openembedded-devel@lists.openembedded.org \
--cc=perceval.arenou@gmail.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).